آردوینو و ماژول سون سگمنت TM1637

saalek110

Well-Known Member
اگر به فکر طراحی یک ساعت، تایمر یا شمارنده افتاده‌اید، پس حتما به یک نمایشگر سون سگمنت 4 رقمی نیاز خواهید داشت. اما متاسفانه نمایشگرهای سون سگمنت 4 رقمی معمولا 12 پایه دارند و این تعداد پایه بسیار زیاد است، زیرا دیگر فضایی برای سایر ماژول‌ها و سنسورها باقی نمی‌ماند.

اما اگر بتوانید بدون این همه سیم کشی، یک نمایشگر سون سگمنت 4 رقمی را کنترل کنید، دیگر نیازی نیست نگران نبود فضا برای سایر ماژول هایتان باشید! خوشبختانه این کار با پیدایش ماژول TM1637 امکان پذیر شده است. زیرا این ماژول تنها چهار پایه دارد. دو پایه برای تغذیه و دو پایه برای کنترل سگمنت‌ها است.

 

saalek110

Well-Known Member

نگاهی به سخت افزار ماژول سون سگمنت TM1637

قبل از اینکه راه اندازی ماژول سون سگمنت TM1637 با آردوینو را شروع کنیم، لازم است سخت افزار این ماژول را بررسی کنیم. در هسته مرکزی این ماژول، یک درایور LED سریال ارزان قیمت وجود دارد که ساخت شرکت Tintan MicroElectronic-TM1637 است.

درایور LED سریال در هسته مرکزی ماژول سون سگمنت TM1637


ماژول TM1637 عملیات‌های گوناگونی را پشتیبانی می‌کند، مانند روشن و خاموش کردن، کنترل روشنایی LEDها و دسترسی به هر سگمنت. البته این ماژول امکان تنظیم شدت نور LEDها در سطح نرم‌افزار را هم برای شما فراهم می‌‎کند. نکته مثبت دیگر در مورد این ماژول این است که با به‌روزرسانی نمایشگر، باعث کاهش حجم کار میکروکنترلر می‌شود و به این ترتیب، میکروکنترلر می‌تواند به انجام فعالیت‌های مهم‌تری بپردازد.

وجود دو نقطه یا کلون در ماژول سون سگمنت 4 رقمی TM1637 برای پروژه‌های مبتنی بر ساعت یا تایمر


ماژول TM1637 شامل 4 عدد سون سگمنت 0.36 اینچی است که به منظور نمایش دما و داده‌های سنسور مورد استفاده قرار می‌گیرد. علاوه بر 4 عدد سون سگمنت، در میانه این ماژول یک نشانه دو نقطه یا کولون :)) قرار دارد که ساخت پروژه‌هایی مبتنی بر ساعت یا تایمر را آسان می‌کند.

این ماژول با ولتاژ 3.3V تا 5V تغذیه می‌شود و از یک باس دو سیمه برای تبادل داده استفاده می‌کند. بنابراین، علاوه بر پایه‌های VCC و GND، تنها به دو پایه دیگر نیاز دارد. اما شاید تصور کنید که تبادل داده تنها با دو سیم دشوار خواهد بود. اما خوشبختانه، آردوینو کتابخانه‌هایی دارد که می‌تواند از پیچیدگی‌های کار کم کند و ارتباط با نمایشگر را آسان‌تر کند.

 

saalek110

Well-Known Member

سالک: با آموزش بالا من توانستم سون سگمت را با آردینو راه بیاندازم. شمارشهای متنوعی انجام می دهد.
کد کاملی است. هر چیزی میشد بنویسی نوشته. مثلا شمارش کرنومتری و یا به شکل ساعت و یا به شکل دما و یا شمارش و حرکت در هر یک از 4 جایگاه و .... کد تنظیم شدت نور هم دارد.
ولی فقط یک بار اجرا میشد. من کاری کردم همه عملیات بارها و بارها اجرا بشه.کد زیر:

کد:
/* Example code for TM1637 4 digit 7 segment display with Arduino. More info: www.www.makerguides.com */
 
// Include the library:
#include <TM1637Display.h>
 
// Define the connections pins:
#define CLK 2
#define DIO 3
 
// Create display object of type TM1637Display:
TM1637Display display = TM1637Display(CLK, DIO);
 
// Create array that turns all segments on:
const uint8_t data[] = {0xff, 0xff, 0xff, 0xff};
 
// Create array that turns all segments off:
const uint8_t blank[] = {0x00, 0x00, 0x00, 0x00};
 
// You can set the individual segments per digit to spell words or create other symbols:
const uint8_t done[] = {
  SEG_B | SEG_C | SEG_D | SEG_E | SEG_G,           // d
  SEG_A | SEG_B | SEG_C | SEG_D | SEG_E | SEG_F,   // O
  SEG_C | SEG_E | SEG_G,                           // n
  SEG_A | SEG_D | SEG_E | SEG_F | SEG_G            // E
};
 
// Create degree Celsius symbol:
const uint8_t celsius[] = {
  SEG_A | SEG_B | SEG_F | SEG_G,  // Circle
  SEG_A | SEG_D | SEG_E | SEG_F   // C
};
 
void setup() {
  // Clear the display:
  display.clear();
  delay(1000);
}
 
void loop() {
   while(1)
   {
  // Set the brightness:
  display.setBrightness(7);
  // All segments on:
  display.setSegments(data);
 
  delay(1000);
  display.clear();
  delay(1000);
 
  // Show counter:
  int i;
  for (i = 0; i < 101; i++) {
    display.showNumberDec(i);
    delay(50);
  }
 
  delay(1000);
  display.clear();
  delay(1000);
 
  // Print number in different locations, loops 2 times:
  int j;
  for (j = 0; j < 2; j++) {
    for (i = 0; i < 4; i++) {
      display.showNumberDec(i, false, 1, i);
      delay(500);
      display.clear();
    }
  }
 
  delay(1000);
  display.clear();
  delay(1000);
 
  // Set brightness (0-7):
  int k;
  for (k = 0; k < 8; k++) {
    display.setBrightness(k);
    display.setSegments(data);
    delay(500);
  }
 
  delay(1000);
  display.clear();
  delay(1000);
 
  // Print 1234 with the center colon:
  display.showNumberDecEx(1234, 0b11100000, false, 4, 0);
 
  delay(1000);
  display.clear();
  delay(1000);
 
  int temperature = 24;
  display.showNumberDec(temperature, false, 2, 0);
  display.setSegments(celsius, 2, 2);
 
  delay(1000);
  display.clear();
  delay(1000);
 
  display.setSegments(done);
   }
  }

من while را اول تابع loop گذاشتم و همه کدها رفتند داخل گیومه. این طوری مدام همه کدها اجرا میشه.

کد:
void loop() {
   while(1)
   {
   ...
  ....
   }
 
   }
 
آخرین ویرایش:

saalek110

Well-Known Member
سالک: یک سال و نیم بعد ، یعنی مهر ۱۴۰۲ . من دوباره اردینو را به سون سگمنت وصل کردم ، همان طوری اجرا شد.
یعنی حافظه موجود در آردوینو پاک نشده بعد یک سال و نیم.

تنها کاری که کردم ، ۴ تاسیم از سون سگمنت ، به اردوینو وصل کردم و تغذیه آردوینو را هم دادم.
 
آخرین ویرایش:

saalek110

Well-Known Member
خوبه سایت مذکور هنوز هست. در پست بعد کپی می کنم مطالبش را....
 

saalek110

Well-Known Member
در این مقاله، راه اندازی ماژول سون سگمنت 4 رقمی TM1637 با آردوینو را آموزش خواهیم داد. این نمایشگر برای نمایش داده‌ی سنسور، دما، زمان و … فوق‌العاده است.

در این مقاله سه مثال آورده شده است. در مثال اول، نگاهی به توابع اصلی کتابخانه‌ی نمایشگر TM1637 خواهیم انداخت. در مثال دوم، به شما نشان خواهیم داد که چطور می‌توانید زمان را بر روی یک نمایشگر 4 رقمی نمایش دهید. از مثال سوم هم می‌توانید برای یک نمایش دمای ساده همراه با سنسور DHT11 استفاده کنید.

نحوه‌ی سیم‌کشی را نیز در این مقاله قرار داده‌ایم. پس از مثال‌ها هم، نحوه‌ی عملکرد کدها را توضیح داده‌‌ایم. بنابراین، شما بدون هیچ مشکلی می‌توانید براساس نیاز خود آن‌ها را تغییر دهید.

قطعات سخت‌افزاری

  • ماژول سون سگمنت 4 رقمی TM1637
  • ماژول آردوینو UNO Rev3
  • بردبورد
  • سیم‌های جامپر (10 عدد)
  • ماژول ساعت DS3231
  • Adafruit DS3231 Precision RTC Breakout
  • سنسور دما و رطوبت DHT11 (3 پایه)
  • کابل USB نوع A/B
نرم افزار

Arduino IDE

اطلاعاتی درباره نمایشگر سون سگمنت

نمایشگرهای سون سگمنت 4 رقمی ساده، معمولاً 12 پایه دارند. این تعداد پایه بسیار زیاد است و فضای زیادی برای سایر ماژول‌ها و سنسورها باقی نمی‌گذارد. به لطف تراشه‌ TM1637 که در پشت ماژول نمایشگر قرارگرفته‌، این تعداد به 4 پایه کاهش پیدا کرده است. از دو پایه برای تغذیه و از دو پایه دیگر برای کنترل سگمنت‌ها استفاده می‌شود.

نمایشگرهای سون سگمنت شامل 7 (یا 8) عدد LED هستند که به‌طور مجزا آدرس‌دهی می‌شوند. سگمنت‌ها با حروف A تا G نام‌گذاری شده‌اند. برخی نمایشگرها نیز دارای یک دات هستند (هشتمین LED). در ادامه هنگام تنظیم سگمنت‌ها در کد، از تصویر زیر به عنوان مرجع استفاده می‌کنیم.

7 LED نام گذاری شده از حروف A تا G و یک دات نمایشگر سون سگمنت

شما می‌توانید ماژول‌های نمایشگر متفاوتی را که از تراشه‌ی TM1637 استفاده می‌کنند، خریداری نمائید. رنگ، سایز، دات‌ها و نقاط اتصال آن‌ها می‌تواند متفاوت باشد. تا زمانی‌که این نمایشگرها از تراشه TM1637 استفاده می‌کنند، کدهای نمونه‌ای که در ادامه بیان کرده‌ایم، قابل استفاده هستند.

در جدول زیر می‌توانید مشخصات اصلی ماژول نمایشگری که در این مقاله استفاده شده یعنی ماژول سون سگمنت TM1637 را مشاهده ‌کنید.

مشخصات ماژول سون سگمنت 4 رقمی TM1637​

جدول مشخصات ماژول سون سگمنت 4 رقمی TM1637

سیم کشی – راه اندازی نمایشگر سون سگمنت 4 رقمی TM1637 به آردوینو UNO

اتصال نمایشگر به یک آردوینو یا سایر میکروکنترلرها بسیار ساده است. تنها لازم است 4 سیم را متصل کنید : 2 سیم برای تغذیه و 2 سیم برای انتقال دیتا.

نمودار سیم‌کشی زیر به شما نشان می‌دهد که چگونه نمایشگر را به آردوینو متصل کنید.


TM1637-4-digit-7-segment-display-with-Arduino-UNO-tutorial-wiring-diagram-schematic-pinout-min...jpg
 

saalek110

Well-Known Member
اتصالات نیز در جدول زیر آورده شده است:

اتصالات نمایشگر سون سگمنت TM1637 به آردوینو

جدول اتصالات نمایشگر سون سگمنت TM1637 به آردوینو

توجه داشته باشید که ترتیب و موقعیت پایه‌های ماژول می‌تواند براساس شرکت سازنده آن متفاوت باشد!

در این مقاله، CLK و DIO به ترتیب به پایه‌های 2 و 3 متصل شده‌اند، اما می‌توانید آن را به هر یک از پایه‌های دیجیتالی که می‌خواهید متصل کنید. تنها باید تنظیمات پایه‌ در کد را طبق آن تغییر دهید.

کد آردوینو برای ماژول سون سگمنت 4 رقمی TM1637

Avishay Orpaz کتابخانه‌ای فوق‌العاده برای نمایشگرهای TM1637 نوشته ‌است. توابع موجود در این کتابخانه، کنترل نمایشگر را آسان می‌کند. این کتابخانه را می‌توانید از طریق لینک زیر دانلود کنید.

توابع اصلی عبارتنداز:

  • ()setSegments – مقدار خام سگمنت‌های هر رقم را تنظیم می‌کند.
  • ()showNumberDec – یک عدد دسیمال را نمایش می‌دهد.
  • ()showNumberDecEx – یک عدد دسیمال با ممیز یا دو نقطه را نمایش می‌دهد.
  • ()setBrightness – روشنایی نمایشگر را تنظیم می‌کند.
  • ()clear – نمایشگر را پاک می‌کند.
کدی که در ادامه قرار دارد، تمام این توابع را نشان می‌دهد. در ادامه، نحوه‌ی استفاده از هر تابع را با جزئیات بیشتری توضیح خواهیم داد.

شما می‌توانید کد نمونه را با استفاده از نرم‌افزار Arduino IDE بر روی آردوینو خود بارگذاری کنید.

برای اینکه بتوانید با تراشه‌ی TM1637 ارتباط برقرار کنید، به یک کتابخانه نیاز دارید. کتابخانه TM1637 را می توانید از لینک زیر دانلود کنید.

کتابخانه TM1637
سپس، مسیر زیر را در نرم‌افزار آردوینو دنبال کنید:

Sketch > Include Library > Add .ZIP Library …

روش دیگر این است که مسیر Tools > Manage Libraries … را دنبال کنید یا اینکه Ctrl + Shift +I را روی ویندوز تایپ کنید. با این کار، Library Manager باز می‌شود و لیست کتابخانه‌های نصب شده به روزرسانی خواهد شد.

سپس، در قسمت جستجو عبارت tm1637 را تایپ و کتابخانه‌ای را که ساخت Avishay Orpaz است، پیدا کنید. در نهایت آخرین نسخه‌ی کتابخانه را انتخاب نموده و بر روی گزینه‌ی نصب کلیک کنید تا کتابخانه نصب شود.

کد نمونه

با کلیک بر روی گزینه‌ای که در گوشه‌ی سمت راست محیط کد قرار دارد، می‌توانید کد را کپی نمائید.
 

saalek110

Well-Known Member
PHP:
 code for TM1637 4 digit 7 segment display with Arduino. More info: www.www.makerguides.com */
 
// Include the library:
#include <TM1637Display.h>
 
// Define the connections pins:
#define CLK 2
#define DIO 3
 
// Create display object of type TM1637Display:
TM1637Display display = TM1637Display(CLK, DIO);
 
// Create array that turns all segments on:
const uint8_t data[] = {0xff, 0xff, 0xff, 0xff};
 
// Create array that turns all segments off:
const uint8_t blank[] = {0x00, 0x00, 0x00, 0x00};
 
// You can set the individual segments per digit to spell words or create other symbols:
const uint8_t done[] = {
  SEG_B | SEG_C | SEG_D | SEG_E | SEG_G,           // d
  SEG_A | SEG_B | SEG_C | SEG_D | SEG_E | SEG_F,   // O
  SEG_C | SEG_E | SEG_G,                           // n
  SEG_A | SEG_D | SEG_E | SEG_F | SEG_G            // E
};
 
// Create degree Celsius symbol:
const uint8_t celsius[] = {
  SEG_A | SEG_B | SEG_F | SEG_G,  // Circle
  SEG_A | SEG_D | SEG_E | SEG_F   // C
};
 
void setup() {
  // Clear the display:
  display.clear();
  delay(1000);
}
 
void loop() {
  // Set the brightness:
  display.setBrightness(7);
  // All segments on:
  display.setSegments(data);
 
  delay(1000);
  display.clear();
  delay(1000);
 
  // Show counter:
  int i;
  for (i = 0; i < 101; i++) {
    display.showNumberDec(i);
    delay(50);
  }
 
  delay(1000);
  display.clear();
  delay(1000);
 
  // Print number in different locations, loops 2 times:
  int j;
  for (j = 0; j < 2; j++) {
    for (i = 0; i < 4; i++) {
      display.showNumberDec(i, false, 1, i);
      delay(500);
      display.clear();
    }
  }
  
  delay(1000);
  display.clear();
  delay(1000);
 
  // Set brightness (0-7):
  int k;
  for (k = 0; k < 8; k++) {
    display.setBrightness(k);
    display.setSegments(data);
    delay(500);
  }
 
  delay(1000);
  display.clear();
  delay(1000);
 
  // Print 1234 with the center colon:
  display.showNumberDecEx(1234, 0b11100000, false, 4, 0);
 
  delay(1000);
  display.clear();
  delay(1000);
 
  int temperature = 24;
  display.showNumberDec(temperature, false, 2, 0);
  display.setSegments(celsius, 2, 2);
 
  delay(1000);
  display.clear();
  delay(1000);
 
  display.setSegments(done);
  while(1);
}
 

saalek110

Well-Known Member

توضیح کد

کدی که در بالا بر روی نرم‌افزار آردوینو آپلود کردید، با معرفی کتابخانه آغاز می‌شود. از نصب شدن کتابخانه‌ی صحیح مطمئن شوید، در غیر این صورت هنگام کامپایل کد پیام خطا دریافت خواهید کرد.

1
2
// Include the library:
#include <TM1637Display.h>
مرحله‌ی بعد تعیین پایه‌های ارتباطی است. برای اختصاص دادن یک نام به یک مقدار ثابت از عبارت define# استفاده می‌شود. هنگامی‌که کد کامپایل می‌شود، کامپایلر هر ارجاعی به مقدار ثابت را با مقدار تعریف شده جایگزین خواهد کرد. بنابراین، هرجا که CLK ذکر شده باشد، هنگامی که کد کامپایل شود، کامپایلر CLK را با مقدار 2 جایگزین می‌کند.

1
2
3
// Define the connections pins:
#define CLK 2
#define DIO 3
در قدم بعد، یک شیء نمایشگر از نوع TM1637Display با پایه‌های CLK و DIO تعریف ‌شده، ایجاد می‌کنیم. توجه داشته باشید که در اینجا ما نمایشگر را display نامیدیم، اما شما می‌توانید از نام‌های دیگر مانند نمایشگر دما (temperature_display) استفاده کنید.

نامی که برای نمایشگر انتخاب می‌کنید، بعداً برای نوشتن دیتا بر روی آن نمایشگر خاص استفاده خواهد شد. شما می‌توانید چندین شیء نمایشگر با نام‌ها و پایه‌های ارتباطی متفاوت ایجاد و آن‌ها را کنترل کنید. در حال حاضر محدودیتی در کتابخانه وجود ندارد.

1
2
3
4
5
6
7
// Create display object of type TM1637Display:
TM1637Display display = TM1637Display(CLK, DIO);

// You can create more than one display object. Give them different names and connection pins:
TM1637Display display_1 = TM1637Display(2, 3);
TM1637Display display_2 = TM1637Display(4, 5);
TM1637Display display_3 = TM1637Display(6, 7);
چندین روش برای کنترل هر یک از سگمنت‌های نمایشگر وجود دارد. پیش از بخش setup دستورات، چندین آرایه تعریف می‌شود که هر یک از سگمنت‌های نمایشگر را تنظیم می‌کند. در ادامه برای نوشتن سگمنت‌ها بر روی نمایشگر از تابع ()setSegments استفاده خواهیم کرد.

اولین روش، نوشتن اعداد در مبنای 16 بر روی هر یک از سگمنت‌های نمایشگر است. عدد 0xFF در مبنای 16 معادل عدد 11111111 در مبنای 2 است که باعث روشن شدن همه‌ی سگمنت‌ها می‌شود (اگر نمایشگر شما دات داشته باشد، آن هم روشن خواهد شد). به عنوان مثال، 0xEF که معادل 11101111 است، همه‌ی سگمنت‌ها را به جز سگمنت E روشن می‌کند. توجه داشته باشید که شمارش از راست به چپ انجام می‌شود، بنابراین، 11111111 به ترتیب با سگمنت‌های (dot)GFEDCBA منطبق است. جدول تبدیل اعداد در مبنای 16 به مبنای 2 را نیز می‌توانید بررسی کنید.

1
2
3
4
5
// Create array that turns all segments on:
const uint8_t data[] = {0xff, 0xff, 0xff, 0xff};

// Create array that turns all segments off:
const uint8_t blank[] = {0x00, 0x00, 0x00, 0x00};
این کتابخانه تابعی دارد که تنظیم هر یک از سگمنت‌ها را آسان‌تر می‌سازد. همان‌طور که در کد زیر مشاهده می‌کنید، شما می‌توانید آرایه‌هایی برای هجی کردن کلمات ایجاد کنید. هر سگمنت با یک | جدا می‌شود و ارقام نمایشگر با یک کاما جدا می‌شوند.

1
2
3
4
5
6
7
// You can set the individual segments per digit to spell words or create other symbols:
const uint8_t done[] = {
SEG_B | SEG_C | SEG_D | SEG_E | SEG_G, // d
SEG_A | SEG_B | SEG_C | SEG_D | SEG_E | SEG_F, // O
SEG_C | SEG_E | SEG_G, // n
SEG_A | SEG_D | SEG_E | SEG_F | SEG_G // E
};
شما می‌توانید بخش setup کد را خالی قرار دهید. ما برای اطمینان از پاک شدن نمایشگر، از تابع ()Clear استفاده می‌کنیم.

1
2
3
4
5
void setup() {
// Clear the display:
display.clear();
delay(1000);
}
در بخش loop کد، چندین مثال از توابع مختلف کتابخانه را نشان می‌دهیم:

setSegments(segments[], length, position)

این تابع برای تنظیم هر یک از سگمنت‌های نمایشگر به‌طور مجزا استفاده می‌شود. اولین پارامتر (segments[]) آرایه‌ای است که شامل اطلاعات سگمنت می‌شود. دومین پارامتر (length) تعداد ارقام (4-0) را که باید تغییر کنند، مشخص می‌کند. اگر بخواهید کلمه‌ی dOnE را هجی کنید، پارامتر دوم برابر با 4 و برای نمایش علامت ˚C، مقدار این پارامتر برابر 2 خواهد بود. سومین پارامتر (position) محلی را که باید از آنجا مقدار نمایشگر چاپ شود، تنظیم می‌کند (0- چپ‌ترین و 3- راست‌ترین). بنابراین، اگر می‌خواهید علامت را روی سومین و چهارمین رقم چاپ کنید، باید از کد زیر استفاده نمائید:

1
2
3
4
5
6
7
// Create degree Celsius symbol:
const uint8_t celsius[] = {
SEG_A | SEG_B | SEG_F | SEG_G, // Circle
SEG_A | SEG_D | SEG_E | SEG_F // C
};

display.setSegments(celsius, 2, 2);
دومین و سومین پارامتر تابع را نیز می‌توانید خالی بگذارید.

showNumberDec(number, leading_zeros, length, position)

این تابع بیشترین کاربرد را برای شما دارد. اولین پارامتر (number) عددی است که می‌خواهید روی نمایشگر نمایش دهید. سایر پارامتر‌ها اختیاری هستند.

دومین پارامتر (leading_zeros) برای روشن کردن یا خاموش کردن صفرهای قبل از عدد به کاربرده می‌شود. عدد 10 بدون صفرهای قبل از عدد به صورت 10— و با صفرهای قبل از عدد به صورت 0010 چاپ خواهد شد. برای نمایش صفرهای قبل از عدد می‌توانید این پارامتر را بر روی true و برای عدم نمایش صفرهای قبل از عدد پارامتر را بر روی false تنظیم کنید. توجه داشته باشید که صفرهای قبل از عدد به ازای اعداد منفی پشتیبانی نمی‌شود.

سومین و چهارمین پارامتر مانند تابع قبلی عمل می‌کنند.

1
2
// Print the number 12 without leading zeros on the second and third digit:
display.showNumberDec(12, false, 2, 1);

showNumberDecEx(number, dots, leading_zeros, length, position)

این تابع به شما این امکان را می‌دهد تا نحوه‌ی قرارگیری ممیز یا نقطه بر روی نمایشگر را کنترل کنید. تنها دومین پارامتر این تابع است که نسبت به تابع showNumberDec متفاوت می‌باشد. دومین پارامتر (dots) تنظیم ممیز یا نقطه بین هر یک از ارقام را برای شما فراهم می‌کند.

در ادامه مقادیری برای شما فراهم شده است که می‌توانید برای کنترل نقطه یا ممیز از آن‌ها استفاده کنید.

برای نمایش نقطه یا ممیز بین هر یک از ارقام از مقادیر زیر استفاده کنید:

  • 0b10000000 – 0.000
  • 0b01000000 – 00.00
  • 0b00100000 – 000.0
  • 0b11100000 – 0.0.0.0
برای نمایش دو نقطه به‌صورت زیر عمل کنید:

  • 0b01000000 – 00:00
برای نمایش نقطه و دو نقطه بین ارقام از مقادیر زیر استفاده کنید:

  • 0b11100000 – 0.0:0.0
برای نمایش ساعت که دو نقطه در مرکز آن قرار دارد، می‌توانید از دستوری مانند زیر استفاده کنید:

1
2
// Print 1234 with the center colon:
display.showNumberDecEx(1234, 0b11100000, false, 4, 0);

setBrightness(brightness, true/false)

این تابع همان‌گونه که از نام آن پیدا است، روشنایی نمایشگر را تنظیم می‌کند. شما می‌توانید سطح روشنایی را از 0 (کمترین حد روشنایی) تا 7 (بیشترین حد روشنایی) مشخص کنید.

از دومین پارامتر (true/false) می‌توان برای روشن یا خاموش کردن نمایشگر استفاده کرد. False به معنای خاموش شدن نمایشگر است.

1
2
// Set the display brightness (0-7):
display.setBrightness(7);
 

saalek110

Well-Known Member
در ادامه ایشان با افزودن یک ماژول دیگر یک ساعت ساخته

و بعد با ماژول دما و رطوبت، مقدار اونها را در سون سگممت نشان داده.
 

جدیدترین ارسال ها

بالا